[Expand all] [Collapse all] # Introduction NSIS 2 makes it is possible to create installers with a custom user interface. The Modern UI is an interface with a style like the wizards of recent Windows versions. This new interface also features new pages (Welcome, Finish, Start Menu) and a description area on the components page. The interface and the graphics can be customized using the provided settings. Using the Modern UI macros and language files, writing scripts with a modern interface is easy. This document contains information about writing Modern UI scripts and a reference of all settings. Important: Because the Modern UI has its own macro system, its own default settings and a lot of new features, the interface configuration works differently. So you should not use commands like LicenseText, Icon, CheckBitmap, InstallColors etc. ### Screenshots # How to use The Modern UI has a macro system, so all the code to control the interface has already been written for you. If you want to start a new Modern UI script or upgrade an older script with the Classic UI, follow the steps below. Taking a look at the example scripts will also help you to learn more about the Modern UI. ## Syntax Some defines (e.g. MUI_COMPONENTSPAGE_SMALLDESC) don't need a value, they are true/false settings. Others (e.g. MUI_UI) can be used to define a specific value. Parameters are specified in this format: required (option1 | option2) [optional] Parameters for defined settings should be in one string:
    !define MUI_COMPONENTSPAGE_SMALLDESC ;No value
    !define MUI_UI "myUI.exe" ;Value
    !define MUI_INSTFILESPAGE_COLORS "FFFFFF 000000" ;Multiple settings
If you want a certain value (e.g. a text) to be language-specific, set a language string (using LangString) and define $(STRINGNAME) as value. Use a license language string (LicenseLangString) for the license text. If you want to add " to a Modern UI string, you should always escape it using $\" because the Modern UI macros use " to separate parameters. ## 1. Header file
    !include "MUI.nsh"
MUI.nsh is in the Include directory, so you don't have to specify a path. ## 2. Interface Configuration Interface settings should be set before inserting page macros. Page interface settings apply to all pages of a certain type. ### Interface Settings ### General Interface Settings MUI_ICON icon_file The icon for the installer. Default: ${NSISDIR}\Contrib\Graphics\Icons\modern-install.ico MUI_UNICON icon_file The icon for the uninstaller. Default: ${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico MUI_HEADERIMAGE Display an image on the header of the page. MUI_HEADERIMAGE_BITMAP bmp_file Bitmap image to display on the header of installers pages (recommended size: 150x57 pixels). Default: ${NSISDIR}\Contrib\Graphics\Header\nsis.bmp MUI_HEADERIMAGE_BITMAP_NOSTRETCH Do not stretch the installer header bitmap to fit the size of the field. Use this option only if you have an image that does not use the whole space. If you have a full size bitmap that fits exactly, you should not use this option because the size of the field will be different if the user has a custom DPI setting. MUI_HEADERIMAGE_BITMAP_RTL bmp_file Bitmap image to display on the header of installers pages when using a RTL language (recommended size: 150x57 pixels). Default: Non-RTL bitmap MUI_HEADERIMAGE_BITMAP_RTL_NOSTRETCH Do not stretch the installer header bitmap when using a RTL language to fit the size of the field. Use this option only if you have an image that does not use the whole space. If you have a full size bitmap that fits exactly, you should not use this option because the size of the field will be different if the user has a custom DPI setting. MUI_HEADERIMAGE_UNBITMAP bmp_file Bitmap image to display on the header of uninstaller pages (recommended size: 150x57 pixels). Default: Installer header bitmap MUI_HEADERIMAGE_UNBITMAP_NOSTRETCH Do not stretch the uninstaller header bitmap to fit the size of the field. Use this option only if you have an image that does not use the whole space. If you have a full size bitmap that fits exactly, you should not use this option because the size of the field will be different if the user has a custom DPI setting. MUI_HEADERIMAGE_UNBITMAP_RTL bmp_file Bitmap image to display on the header of uninstallers pages when using a RTL language (recommended size: 150x57 pixels). Default: Installer RTL header bitmap MUI_HEADERIMAGE_UNBITMAP_RTL_NOSTRETCH Do not stretch the uninstaller header bitmap when using a RTL language to fit the size of the field. Use this option only if you have an image that does not use the whole space. If you have a full size bitmap that fits exactly, you should not use this option because the size of the field will be different if the user has a custom DPI setting. MUI_HEADERIMAGE_RIGHT Display the header image on the right side instead of the left side (when using a RTL language it will be displayed on the left side instead of the right side). MUI_BGCOLOR (color: RRGGBBR hexadecimal) Background color for the header, the Welcome page and the Finish page. Default: FFFFFF ### Interface Resource Settings MUI_UI ui_file The interface file with the dialog resources. Change this if you have made your own customized UI. Default: ${NSISDIR}\Contrib\UIs\modern.exe MUI_UI_HEADERIMAGE ui_file The interface files with the dialog resource IDD_INST that contains a bitmap control and space for the header bitmap. Default: ${NSISDIR}\Contrib\UIs\modern_headerbmp.exe MUI_UI_HEADERIMAGE_RIGHT ui_file The interface files with the dialog resource IDD_INST that contains a bitmap control and space for the header bitmap on the right side. Default: ${NSISDIR}\Contrib\UIs\modern_headerbmpr.exe MUI_UI_COMPONENTSPAGE_SMALLDESC ui_file The interface files with a customized dialog resource IDD_SELCOM with a small description area. Default: ${NSISDIR}\Contrib\UIs\modern_smalldesc.exe MUI_UI_COMPONENTSPAGE_NODESC ui_file The interface files with a customized dialog resource IDD_SELCOM without a description area. Default: ${NSISDIR}\Contrib\UIs\modern_nodesc.exe ### Welcome/Finish Page Interface Settings MUI_WELCOMEFINISHPAGE_BITMAP bmp_file Bitmap for the Welcome page and the Finish page (recommended size: 164x314 pixels). Default: ${NSISDIR}\Contrib\Graphics\Wizard\win.bmp MUI_WELCOMEFINISHPAGE_BITMAP_NOSTRETCH Do not stretch the bitmap for the Welcome and Finish page to fit the size of the field. Use this option only if you have an image that does not use the whole space. If you have a full size bitmap that fits exactly, you should not use this option because the size of the field will be different if the user has a custom DPI setting. ### Welcome/Finish Page InstallOptions INI Settings MUI_WELCOMEFINISHPAGE_INI ini_file InstallOptions INI file for the Welcome page and the Finish page. Default: ${NSISDIR}\Contrib\Modern UI\ioSpecial.ini ### Uninstaller Welcome/Finish Page Settings MUI_UNWELCOMEFINISHPAGE_BITMAP bmp_file Bitmap for the Welcome page and the Finish page (recommended size: 164x314 pixels). Default: ${NSISDIR}\Contrib\Graphics\Wizard\win.bmp MUI_UNWELCOMEFINISHPAGE_BITMAP_NOSTRETCH Do not stretch the bitmap for the Welcome and Finish page to fit the size of the field. Use this option only if you have an image that does not use the whole space. If you have a full size bitmap that fits exactly, you should not use this option because the size of the field will be different if the user has a custom DPI setting. ### Uninstaller Welcome/Finish Page Interface INI Settings MUI_UNWELCOMEFINISHPAGE_INI ini_file InstallOptions INI file for the uninstaller Welcome page and the Finish page. Default: ${NSISDIR}\Contrib\Modern UI\ioSpecial.ini ### License Page Interface Settings MUI_LICENSEPAGE_BGCOLOR (/windows | /grey | (color: RRGGBB hexadecimal)) The background color for the license textbox. Use /windows for the Windows text background color (usually white). Use the /grey for the window background color (usually grey). Default: /windows ### Components Page Interface Settings MUI_COMPONENTSPAGE_CHECKBITMAP bitmap_file The bitmap with images for the checks of the component select treeview. Default: ${NSISDIR}\Contrib\Graphics\Checks\modern.bmp MUI_COMPONENTSPAGE_SMALLDESC A small description area on the bottom of the page. Use this layout if you have a lot of sections and don't need large descriptions. MUI_COMPONENTSPAGE_NODESC No description area. ### Installation Page Interface Settings MUI_INSTFILESPAGE_COLORS (/windows | (foreground color: RRGGBB hexadecimal) (background color: RRGGBB hexadecimal)) The colors of the details screen. Use /windows for the default Windows colors. Default: /windows MUI_INSTFILESPAGE_PROGRESSBAR ("" | colored | smooth) The style of the progress bar. Colored makes it use the MUI_INSTALLCOLORS. Default: smooth ### Installer Finish Page Interface Settings MUI_FINISHPAGE_NOAUTOCLOSE Do not automatically jump to the finish page, to allow the user to check the install log. ### Uninstaller Finish Page Interface Settings MUI_UNFINISHPAGE_NOAUTOCLOSE Do not automatically jump to the finish page, to allow the user to check the uninstall log. ### Abort Warning Settings MUI_ABORTWARNING Show a message box with a warning when the user wants to close the installer. MUI_ABORTWARNING_TEXT text Text to display on the abort warning messagebox. ### Uninstaller Abort Warning Settings MUI_UNABORTWARNING Show a message box with a warning when the user wants to close the uninstaller. MUI_UNABORTWARNING_TEXT text Text to display on the abort warning messagebox. ## 3. Pages Insert the following macros to set the pages you want to use. The pages will appear in the order you insert them in your script. You can also insert custom Page commands between the macros to add custom pages. More info about custom pages... You can add multiple pages of certain types (for example, if you want the user to specify multiple folders). Examples:
    !insertmacro MUI_PAGE_LICENSE "License.rtf"
    !insertmacro MUI_PAGE_COMPONENTS

    Var STARTMENU_FOLDER
    !insertmacro MUI_PAGE_STARTMENU "Application" $STARTMENU_FOLDER
You will need the page ID for the Start Menu Folder page when using the Start Menu Folder macros. The Start Menu Folder will be stored in the specified variable. Installer Pages MUI_PAGE_WELCOME MUI_PAGE_LICENSE text/rtf_file MUI_PAGE_COMPONENTS MUI_PAGE_DIRECTORY MUI_PAGE_STARTMENU page_id variable MUI_PAGE_INSTFILES MUI_PAGE_FINISH Uninstaller Pages MUI_UNPAGE_WELCOME MUI_UNPAGE_CONFIRM MUI_UNPAGE_LICENSE text/rtf_file MUI_UNPAGE_COMPONENTS MUI_UNPAGE_DIRECTORY MUI_UNPAGE_INSTFILES MUI_UNPAGE_FINISH ### Page Settings Page Settings apply to a single page and should be set before inserting a page macro. If you have multiple pages of one type and you want to set a setting for all them, put the setting before each page macro. Example:
    ;Add a directory page to let the user specify a plug-ins folder
    ;Store the folder in $PLUGINS_FOLDER

    Var PLUGINS_FOLDER
    !define MUI_DIRECTORYPAGE_VARIABLE $PLUGINS_FOLDER
    !insertmacro MUI_PAGE_DIRECTORY
Note: There is no difference between installer and uninstaller page settings. ### General Page Settings MUI_PAGE_HEADER_TEXT text Text to display on the header of the page. MUI_PAGE_HEADER_SUBTEXT text Subtext to display on the header of the page. ### Welcome Page Settings MUI_WELCOMEPAGE_TITLE title Title to display on the top of the page. MUI_WELCOMEPAGE_TITLE_3LINES Extra space for the title area. MUI_WELCOMEPAGE_TEXT text Text to display on the page. Use \r\n for a newline. ### License Page Settings MUI_LICENSEPAGE_TEXT_TOP text Text to display on the top of the page. MUI_LICENSEPAGE_TEXT_BOTTOM text Text to display on the bottom of the page. MUI_LICENSEPAGE_BUTTON button_text Text to display on the 'I Agree' button. MUI_LICENSEPAGE_CHECKBOX Display a checkbox the user has to check to agree with the license terms. MUI_LICENSEPAGE_CHECKBOX_TEXT text Text to display next to the checkbox to agree with the license terms. MUI_LICENSEPAGE_RADIOBUTTONS Display two radio buttons to allow the user to choose between accepting the license terms or not. MUI_LICENSEPAGE_RADIOBUTTONS_TEXT_ACCEPT text Text to display next to the checkbox to accept the license terms. MUI_LICENSEPAGE_RADIOBUTTONS_TEXT_DECLINE text Text to display next to the checkbox to decline the license terms. ### Components Page Settings MUI_COMPONENTSPAGE_TEXT_TOP text Text to display on the top of the page. MUI_COMPONENTSPAGE_TEXT_COMPLIST text Text to display on next to the components list. MUI_COMPONENTSPAGE_TEXT_INSTTYPE text Text to display on next to the installation type combo box. MUI_COMPONENTSPAGE_TEXT_DESCRIPTION_TITLE text Text to display on the of the top of the description box. MUI_COMPONENTSPAGE_TEXT_DESCRIPTION_INFO text Text to display inside the description box when no section is selected. ### Directory Page Settings MUI_DIRECTORYPAGE_TEXT_TOP text Text to display on top of the page. MUI_DIRECTORYPAGE_TEXT_DESTINATION text Text to display on the destination folder frame. MUI_DIRECTORYPAGE_VARIABLE variable Variable in which to store the selected folder. Default: $INSTDIR MUI_DIRECTORYPAGE_VERIFYONLEAVE Does not disable the Next button when a folder is invalid but allows you to use GetInstDirError in the leave function to handle an invalid folder. ### Start Menu Folder Page Settings Put the code to write the shortcuts (using CreateShortcut) between the MUI_STARTMENU_WRITE_BEGIN and MUI_STARTMENU_WRITE_END macros:
    !insertmacro MUI_STARTMENU_WRITE_BEGIN page_id
      ...create shortcuts...
    !insertmacro MUI_STARTMENU_WRITE_END
The page ID should be the ID of the page on which the user has selected the folder for the shortcuts you want to write. MUI_STARTMENUPAGE_TEXT_TOP text Text to display on the top of the page. MUI_STARTMENUPAGE_TEXT_CHECKBOX text Text to display next to the checkbox to disable the Start Menu folder creation. MUI_STARTMENUPAGE_DEFAULTFOLDER folder The default Start Menu Folder. MUI_STARTMENUPAGE_NODISABLE Do not display the checkbox to disable the creation of Start Menu shortcuts. MUI_STARTMENUPAGE_REGISTRY_ROOT root MUI_STARTMENUPAGE_REGISTRY_KEY key MUI_STARTMENUPAGE_REGISTRY_VALUENAME value_name The registry key to store the Start Menu folder. The page will use it to remember the users preference. You should also use for the uninstaller to remove the Start Menu folders. Don't forget to remove this key during uninstallation. For the uninstaller, use the MUI_STARTMENU_GETFOLDER macro to get the Start Menu folder:
    !insertmacro MUI_STARTMENU_GETFOLDER page_id $R0
      Delete "$SMPROGRAMS\$R0\Your Shortcut.lnk"
### Installation Page Settings MUI_INSTFILESPAGE_FINISHHEADER_TEXT text Text to display on the header of the installation page when the installation has been completed (won't be displayed when using a Finish page without MUI_(UN)FINISHPAGE_NOAUTOCLOSE). MUI_INSTFILESPAGE_FINISHHEADER_SUBTEXT text Subtext to display on the header of the installation page when the installation has been completed (won't be displayed when using a Finish page without MUI_(UN)FINISHPAGE_NOAUTOCLOSE). MUI_INSTFILESPAGE_ABORTHEADER_TEXT text Text to display on the header of the installation page when the installation has been aborted. MUI_INSTFILESPAGE_ABORTHEADER_SUBTEXT text Subext to display on the header of the installation page when the installation has been aborted. ### Finish Page Settings MUI_FINISHPAGE_TITLE title Title to display on the top of the page. MUI_FINISHPAGE_TITLE_3LINES Extra space for the title area. MUI_FINISHPAGE_TEXT text Text to display on the page. Use \r\n for a newline. MUI_FINISHPAGE_TEXT_LARGE Extra space for the text area (if using checkboxes). MUI_FINISHPAGE_BUTTON text Text to display on the Finish button. MUI_FINISHPAGE_TEXT_REBOOT text Text to display on the finish page when asking for a system reboot. Use \r\n for a newline. MUI_FINISHPAGE_TEXT_REBOOTNOW text Text to display next to the 'Reboot now' option button. MUI_FINISHPAGE_TEXT_REBOOTLATER text Text to display next to the 'Reboot later' option button. MUI_FINISHPAGE_RUN exe_file Application which the user can select to run using a checkbox. You don't need to put quotes around the filename when it contains spaces. MUI_FINISHPAGE_RUN_TEXT text Texts to display next to the 'Run program' checkbox. MUI_FINISHPAGE_RUN_PARAMETERS parameters Parameters for the application to run. Don't forget to escape double quotes in the value (use $\"). MUI_FINISHPAGE_RUN_NOTCHECKED Do not check the 'Run program' checkbox by default MUI_FINISHPAGE_RUN_FUNCTION function_name Call a function instead of executing an application (define MUI_FINISHPAGE_RUN without parameters). You can use the function to execute multiple applications or you can change the checkbox name and use it for other things. MUI_FINISHPAGE_SHOWREADME file/url File or website which the user can select to view using a checkbox. You don't need to put quotes around the filename when it contains spaces. MUI_FINISHPAGE_SHOWREADME_TEXT text Texts to display next to the 'Show Readme' checkbox. MUI_FINISHPAGE_SHOWREADME_NOTCHECKED Do not check the 'Show Readme' checkbox by default MUI_FINISHPAGE_SHOWREADME_FUNCTION function_name Call a function instead of showing a file (define MUI_FINISHPAGE_SHOWREADME without parameters). You can use the function to show multiple files or you can change the checkbox name and use it for other things. MUI_FINISHPAGE_LINK link_text Text for a link on the which the user can click to view a website or file. MUI_FINISHPAGE_LINK_LOCATION file/url Website or file which the user can select to view using the link. You don't need to put quotes around the filename when it contains spaces. MUI_FINISHPAGE_LINK_COLOR (color: RRGGBB hexadecimal) Text color for the link on the Finish page. Default: 000080 MUI_FINISHPAGE_NOREBOOTSUPPORT Disables support for the page that allows the user to reboot the system. Define this option to save some space if you are not using the /REBOOTOK flag or SetRebootFlag. ### Uninstall Confirm Page Settings MUI_UNCONFIRMPAGE_TEXT_TOP text Text to display on the top of the page. MUI_UNCONFIRMPAGE_TEXT_LOCATION text Text to display next to the uninstall location text box. ### Advanced Page Settings You can add custom code to the page functions of your Modern UI pages. More info... ## 4. Custom functions If you want add your own code to functions inserted by the Modern UI (e.g. the .onGUIInit function and the page functions), create your own function and let the Modern UI functions call them. More info... ## 5. Language files Insert the Modern UI language files for the languages to want to include.
    !insertmacro MUI_LANGUAGE "English"
The Modern UI language files load the NLF language files, so you should not use LoadLanguageFile. ### Language Selection Dialog If you want the installer to display a language selection dialog (have a look at the MultiLanguage.nsi example), insert the MUI_LANGDLL_DISPLAY macro in the .onInit function:
    Function .onInit

      !insertmacro MUI_LANGDLL_DISPLAY

    FunctionEnd
You can also use this macro for the uninstaller, in the un.onInit function. ### Language Selection Dialog Settings To remember the user's preference, you can define a registry key. Note: These defines should be set before inserting the installation page macro. MUI_LANGDLL_REGISTRY_ROOT root MUI_LANGDLL_REGISTRY_KEY key MUI_LANGDLL_REGISTRY_VALUENAME value_name The registry key to store the language. The users preference will be remembered. You can also use it for the uninstaller to display the right language. Don't forget to remove this key in the uninstaller. For the uninstaller, insert the MUI_UNGETLANGUAGE macro in un.onInit to get the stored language preference:
    Function un.onInit

      !insertmacro MUI_UNGETLANGUAGE

    FunctionEnd
### Language Selection Dialog Interface Settings To customize the language selection dialog interface, use these defines before inserting the MUI_LANGDLL_DISPLAY macro. MUI_LANGDLL_WINDOWTITLE text The window title of the language selection dialog. MUI_LANGDLL_INFO text The text to display on the language selection dialog. MUI_LANGDLL_ALWAYSSHOW Always show the language selection dialog, even if a language has been stored in the registry. The language stored in the registry will be selected by default. ## 6. Reserve files If you are using solid compression, it's important that files which are being extracted in init- or page functions function are located before other files in the data block, because this will make your installer faster. If there are File commands in your sections or functions above the init- or page functions, add the reserve file macros above your sections and functions.
    ReserveFile "ioFile.ini" ;Your own InstallOptions INI files
    !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS ;InstallOptions plug-in
    !insertmacro MUI_RESERVEFILE_LANGDLL ;Language selection dialog
## 7. Your own sections and functions Add your installer sections and functions. See the NSIS Users Manual for details. Information about section code and function code for Start Menu shortcut creation and language selection can be found above. ## 8. Section descriptions The descriptions of sections will be displayed on the components page, when the user hovers the mouse over a section. If you don't want to use descriptions, use the MUI_COMPONENTSPAGE_NODESC interface setting. To set a description for a section, you have to add an additional parameter to the Section commmand with a name for the define that should contain the section number.
    Section "Section Name 1" Section1
       ...
    SectionEnd
Use these macros to set the descriptions:
    LangString DESC_Section1 ${LANG_ENGLISH} "Description of section 1."
    LangString DESC_Section2 ${LANG_ENGLISH} "Description of section 2."

    !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
      !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
      !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
    !insertmacro MUI_FUNCTION_DESCRIPTION_END
For the uninstaller, use the MUI_UNFUNCTION_DESCRIPTION_BEGIN and MUI_UNFUNCTION_DESCRIPTION_END macros. # Custom pages If you want add your custom pages to your installer, you should insert your own page commands between the page macros.
    !insertmacro MUI_PAGE_WELCOME
    Page custom FunctionName ;Custom page
    !insertmacro MUI_PAGE_COMPONENTS

    ;Uninstaller
    !insertmacro MUI_UNPAGE_CONFIRM
    UninstPage custom un.FunctionName ;Custom page
    !insertmacro MUI_UNPAGE_INSTFILES
### Using InstallOptions for custom pages InstallOptions is a plug-in that displays custom pages that you can create using INI files. Have a look at the InstallOptions documentation for info about creating InstallOptions INI files. First, you have to extract your InstallOptions INI File in the .onInit function (un.onInit for the uninstaller) using the MUI_INSTALLOPTIONS_EXTRACT macro:
    Function .onInit
      !insertmacro MUI_INSTALLOPTIONS_EXTRACT "ioFile.ini"
    FunctionEnd
If your INI File is located in another directory, use MUI_INSTALLOPTIONS_EXTRACT_AS. The second parameter is the filename for the temporary plug-ins directory, use this filename as parameter for the other InstallOptions macros.
    Function .onInit
      !insertmacro MUI_INSTALLOPTIONS_EXTRACT_AS "..\ioFile.ini" "ioFile.ini"
    FunctionEnd
You can call Instal Options in the function defined with the Page or UninstPage command using the MUI_INSTALLOPTIONS_DISPLAY macro. Use the MUI_HEADER_TEXT macro to set the text on the page header:
    LangString TEXT_IO_TITLE ${LANG_ENGLISH} "Install Options Page Title"
    LangString TEXT_IO_SUBTITLE ${LANG_ENGLISH} "A subtitle"

    Function FunctionName ;FunctionName defined with Page command
      !insertmacro MUI_HEADER_TEXT "$(TEXT_IO_TITLE)" "$(TEXT_IO_SUBTITLE)"
      !insertmacro MUI_INSTALLOPTIONS_DISPLAY "ioFile.ini"
    FunctionEnd
For custom fonts and colors, macros for the initDialog and show functions of InstallOptions are also available:
    Var HWND
    Var DLGITEM
    Var FONT

    LangString TEXT_IO_TITLE ${LANG_ENGLISH} "Install Options Page Title"
    LangString TEXT_IO_SUBTITLE ${LANG_ENGLISH} "A subtitle"

    Function FunctionName ;FunctionName defined with Page command

      !insertmacro MUI_HEADER_TEXT "$(TEXT_IO_TITLE)" "$(TEXT_IO_SUBTITLE)"

      !insertmacro MUI_INSTALLOPTIONS_INITDIALOG "ioFile.ini"
      Pop $HWND ;HWND of dialog

      GetDlgItem $DLGITEM $HWND 1200 ;1200 + Field number - 1

      ;$DLGITEM contains the HWND of the first field
      CreateFont $FONT "Tahoma" 10 700
      SendMessage $DLGITEM ${WM_SETFONT} $FONT 0

      !insertmacro MUI_INSTALLOPTIONS_SHOW

    FunctionEnd
If you need the InstallOptions return value (success, back, cancel, error), use the MUI_INSTALLOPTIONS_DISPLAY_RETURN or MUI_INSTALLOPTIONS_SHOW_RETURN macro. The return value will be added to the stack, so you can use the Pop command to get it. Use these macros to read or write INI file values:
    !insertmacro MUI_INSTALLOPTIONS_READ $VAR "ioFile.ini" "Field #" "Name"
    !insertmacro MUI_INSTALLOPTIONS_WRITE "ioFile.ini" "Field #" "Name" "Value"
For example, you can use the MUI_INSTALLOPTIONS_READ macro in a section to get the user input:
    !insertmacro MUI_INSTALLOPTIONS_READ $R0 "ioFile.ini" "Field 1" "State"
For more details about InstallOptions, validation of user input etc., check the InstallOptions documentation. ### Customize standard dialogs To change elements on the dialogs, use customized UI resource files (see Interface Configuration). You can change your copies of the original files (in the Contrib\UIs folder) by using an application such as Resource Hacker. The 'Please wait while Setup is loading...' text on the splash screen that is being displayed while the installer is starting (Verifying installer, Unpacking data) can be changed by using a customized UI resource file (MUI_UI setting) with a modified dialog 111. The 'Verifying installer' and 'Unpacking data' texts are defined in the language header file of the NSIS exehead (Source\exehead\lang.h). To change them, you have to edit this file and recompile NSIS. To modify the Welcome dialog and Finish dialog, use a custom INI file (MUI_SPECIALINI setting) or write to the INI file in the custom page functions. # Customize Modern UI Functions If you want add your own code to functions inserted by the Modern UI, such as the .onGUIInit function and the Page functions, create your own function and let the Modern UI functions call them. Use the defines to define the name of your functions. Example:
    !define MUI_CUSTOMFUNCTION_GUIINIT myGuiInit

    Function myGUIInit
      ...your own code...
    FunctionEnd
### General Custom Functions These defines should be set before inserting the language macros. MUI_CUSTOMFUNCTION_GUIINIT function MUI_CUSTOMFUNCTION_UNGUIINIT function MUI_CUSTOMFUNCTION_ABORT function MUI_CUSTOMFUNCTION_UNABORT function ### Page Custom Functions These defines should be set before inserting a page macro. MUI_PAGE_CUSTOMFUNCTION_PRE function MUI_PAGE_CUSTOMFUNCTION_SHOW function MUI_PAGE_CUSTOMFUNCTION_LEAVE function Notes: The StartMenu page does not have a Show function In the Pre function of the Welcome page and the Finish page, you can write to the InstallOptions INI file of the page (ioSpecial.ini) In the Show function of Welcome page and the Finish page, $MUI_HWND contains the HWND of the inner dialog ### Welcome/Finish Page Custom Functions This define should be inserted before a single Welcome or Finish page. MUI_WELCOMEFINISHPAGE_CUSTOMFUNCTION_INIT function This Init function is called before the InstallOptions INI file for the page is written, so you can use it to initialize any variables used in the page settings. # Examples Basic: Basic.nsi Welcome/Finish page: WelcomeFinish.nsi Multiple languages: MultiLanguage.nsi Header image: HeaderBitmap.nsi Custom pages: InstallOptions.nsi Start Menu Folder page: StartMenu.nsi # Version history 1.74 - September 4, 2005 Fixed compile error when checkboxes are used on multiple finish page pages Complete version history # Credits Made by Joost Verburg. Icons designed by Nikos Adamamas, aka adni18. Thanks to Amir Szekely, aka KiCHiK, for his work on NSIS to make this possible. # Help Please post questions at the NSIS Forum. # License The zlib/libpng license applies to the Modern UI. ### License Terms
    Copyright © 2002-2006 Joost Verburg

    This software is provided 'as-is', without any express or implied
    warranty. In no event will the authors be held liable for any damages
    arising from the use of this software.

    Permission is granted to anyone to use this software for any purpose,
    including commercial applications, and to alter it and redistribute
    it freely, subject to the following restrictions:

    1. The origin of this software must not be misrepresented;
       you must not claim that you wrote the original software.
       If you use this software in a product, an acknowledgment in the
       product documentation would be appreciated but is not required.
    2. Altered versions must be plainly marked as such,
       and must not be misrepresented as being the original software.
    3. This notice may not be removed or altered from any distribution.